windows-itpro-docs/windows/security/threat-protection/microsoft-defender-atp/advanced-hunting-query-language.md

title, description, keywords, search.product, search.appverid, ms.prod, ms.mktglfcycl, ms.sitesec, ms.pagetype, ms.author, author, ms.localizationpriority, manager, audience, ms.collection, ms.topic

title	description	keywords	search.product	search.appverid	ms.prod	ms.mktglfcycl	ms.sitesec	ms.pagetype	ms.author	author	ms.localizationpriority	manager	audience	ms.collection	ms.topic
Learn the advanced hunting query language	Create your first threat hunting query and learn about common operators and other aspects of the advanced hunting query language	advanced hunting, threat hunting, cyber threat hunting, mdatp, microsoft defender atp, wdatp search, query, language, learn, first query, telemetry, events, telemetry, custom detections, schema, kusto, operators, data types	eADQiWindows 10XVcnh	met150	w10	deploy	library	security	lomayor	lomayor	medium	dansimp	ITPro	M365-security-compliance	article

Learn the advanced hunting query language

Applies to:

• Microsoft Defender Advanced Threat Protection (Microsoft Defender ATP)

Want to experience Microsoft Defender ATP? Sign up for a free trial.

Advanced hunting is based on the Kusto query language. You can use Kusto syntax and operators to construct queries that locate information in the schema specifically structured for advanced hunting. To understand these concepts better, run your first query.

Try your first query

In Microsoft Defender Security Center, go to Advanced hunting to run your first query. Use the following example:

// Finds PowerShell execution events that could involve a download
union DeviceProcessEvents, DeviceNetworkEvents
| where Timestamp > ago(7d)
// Pivoting on PowerShell processes
| where FileName in~ ("powershell.exe", "powershell_ise.exe")
// Suspicious commands
| where ProcessCommandLine has_any("WebClient",
    "DownloadFile",
    "DownloadData",
    "DownloadString",
    "WebRequest",
    "Shellcode",
    "http",
    "https")
| project Timestamp, DeviceName, InitiatingProcessFileName, InitiatingProcessCommandLine, 
FileName, ProcessCommandLine, RemoteIP, RemoteUrl, RemotePort, RemoteIPType
| top 100 by Timestamp

This is how it will look like in advanced hunting.

Describe the query and specify the tables to search

A short comment has been added to the beginning of the query to describe what it is for. This helps if you later decide to save the query and share it with others in your organization.

// Finds PowerShell execution events that could involve a download

The query itself will typically start with a table name followed by a series of elements started by a pipe (|). In this example, we start by creating a union of two tables, DeviceProcessEvents and DeviceNetworkEvents, and add piped elements as needed.

union DeviceProcessEvents, DeviceNetworkEvents

Set the time range

The first piped element is a time filter scoped to the previous seven days. Keeping the time range as narrow as possible ensures that queries perform well, return manageable results, and don't time out.

| where Timestamp > ago(7d)

Check specific processes

The time range is immediately followed by a search for process file names representing the PowerShell application.

// Pivoting on PowerShell processes
| where FileName in~ ("powershell.exe", "powershell_ise.exe")

Search for specific command strings

Afterwards, the query looks for strings in command lines that are typically used to download files using PowerShell.

// Suspicious commands
| where ProcessCommandLine has_any("WebClient",
    "DownloadFile",
    "DownloadData",
    "DownloadString",
    "WebRequest",
    "Shellcode",
    "http",
    "https")

Customize result columns and length

Now that your query clearly identifies the data you want to locate, you can add elements that define what the results look like. project returns specific columns, and top limits the number of results. These operators help ensure the results are well-formatted and reasonably large and easy to process.

| project Timestamp, DeviceName, InitiatingProcessFileName, InitiatingProcessCommandLine, 
FileName, ProcessCommandLine, RemoteIP, RemoteUrl, RemotePort, RemoteIPType
| top 100 by Timestamp

Click Run query to see the results. Select the expand icon at the top right of the query editor to focus on your hunting query and the results.

Tip

You can view query results as charts and quickly adjust filters. For guidance, read about working with query results

Learn common query operators for advanced hunting

Now that you've run your first query and have a general idea of its components, it's time to backtrack a little bit and learn some basics. The Kusto query language used by advanced hunting supports a range of operators, including the following common ones.

Operator	Description and usage
where	Filter a table to the subset of rows that satisfy a predicate.
summarize	Produce a table that aggregates the content of the input table.
join	Merge the rows of two tables to form a new table by matching values of the specified column(s) from each table.
count	Return the number of records in the input record set.
top	Return the first N records sorted by the specified columns.
limit	Return up to the specified number of rows.
project	Select the columns to include, rename or drop, and insert new computed columns.
extend	Create calculated columns and append them to the result set.
makeset	Return a dynamic (JSON) array of the set of distinct values that Expr takes in the group.
find	Find rows that match a predicate across a set of tables.

To see a live example of these operators, run them from the Get started section of the advanced hunting page.

Understand data types

Data in advanced hunting tables are generally classified into the following data types.

Data type	Description and query implications
datetime	Data and time information typically representing event timestamps
string	Character string
bool	True or false
int	32-bit numeric value
long	64-bit numeric value

Use sample queries

The Get started section provides a few simple queries using commonly used operators. Try running these queries and making small modifications to them.

Note

Apart from the basic query samples, you can also access shared queries for specific threat hunting scenarios. Explore the shared queries on the left side of the page or the GitHub query repository.

Access comprehensive query language reference

For detailed information about the query language, see Kusto query language documentation.

Related topics

• Advanced hunting overview
• Work with query results
• Understand the schema
• Apply query best practices

Want to experience Microsoft Defender ATP? Sign up for a free trial.